Hi ​@Rohit_809 Kumar ,

It sounds like you want to show the Support values aggregated up to the vendor, os and os version level. You can use a “group” statement to do that. Here is a version that does that:

foreach device in network.devices
let platform = device.platform
let osSupport = platform.osSupport
where isPresent(osSupport)
group osSupport as osSupports
  by { vendor: platform.vendor, os: platform.os, osVersion: platform.osVersion
    }
    as platformInfo
foreach osSupport in distinct(osSupports)
select {
  Vendor: platformInfo.vendor,
  OS: platformInfo.os,
  "OS Version": platformInfo.osVersion,
  "End of OS maintenance": osSupport.lastMaintenanceDate,
  "End of OS vulnerability": osSupport.lastVulnerabilityDate,
  "End of OS support": osSupport.lastSupportDate,
  URL: osSupport.announcementUrl
}

Thanks ​@Andreas  , this is working for me , can we add also total no of devices that belong to same ios or model .

Hi Rohit,

This will give you the device count for each OS

foreach device in network.devices
let platform = device.platform
let osSupport = platform.osSupport
where isPresent(osSupport)
group device.name as devices
  by { vendor: platform.vendor, os: platform.os, osVersion: platform.osVersion, osSupport
    }
    as platformInfo

select {
  Vendor: platformInfo.vendor,
  OS: platformInfo.os,
  "OS Version": platformInfo.osVersion,
  deviceCount: length(devices),
  "End of OS maintenance": platformInfo.osSupport.lastMaintenanceDate,
  "End of OS vulnerability": platformInfo.osSupport.lastVulnerabilityDate,
  "End of OS support": platformInfo.osSupport.lastSupportDate,
  URL: platformInfo.osSupport.announcementUrl
}